phpsh hpcli開発の究極のソリューション（php版切り替えバッチ処理）

@echo off
 
::Installation path
set ins=C:\Windows\%~nx0
 
::If the corresponding PHP version exists, go to the main program
if "%1"=="" goto main
if "%1"=="52" goto main
if "%1"=="53" goto main
if "%1"=="53n" goto main
if "%1"=="55" goto main
if "%1"=="55n" goto main
if "%1"=="70n" goto main
goto cmds
 
::main program
:main
set PHP_VER=PHP%1
if "%PHP_VER%" == "PHP" set PHP_VER=PHP55
set path=d:\phpstudy\%PHP_VER%;%path%
title %PHP_VER%_sh
prompt %PHP_VER%_sh^>$p#
goto quit
 
::If it is a non-numeric parameter that is entered, parse
:cmds
if "%1"=="/i" goto install
if "%1"=="/install" goto install
if "%1"=="/u" goto uninstall
if "%1"=="/uninstall" goto uninstall
if "%1"=="/v" goto version
if "%1"=="/version" goto version
goto help
 
::Show help
:help
echo Usage: %~n0 [/h ^| /help ^| /i ^| /install ^| /u ^| /unstall ^| /v ^| /version ^| PHP_VERSION]
echo.
echo no arguments set php version to php5.5
echo /h Show help
echo /help Show help, same as /h
echo /i install to system
echo /install install to system, same as /i
echo /u uninstall
echo /unstall uninstall, same as /u
echo /v View current php version
echo /version View current php version, same as /u
echo 52 set php version to php5.2
echo 53 set php version to php5.3
echo 53n set php version to php5.3n
echo 55 set php version to php5.5
echo 55n set php version to php5.5n
echo 70n set php version to php7.0n
goto quit
 
::view version
:version
php --version
goto quit
 
::install
:install
echo Start installation...
if not exist %ins% copy %~f0 %ins%>nul
if %ERRORLEVEL% == 0 echo Installation successful, open the command prompt and type %~n0 to start
if %ERRORLEVEL% == 1 echo Installation failed, must be run in administrator mode
goto quit
 
::Uninstall failed
:uninstallerror
echo Uninstallation failed, must run in administrator mode
goto quit
 
::Uninstall
:uninstall
copy %~f0 %ins%.bak>nul
if %ERRORLEVEL% == 1 goto uninstallerror
echo uninstall successful
del %ins%.bak>nul
if exist %ins% del %ins%
 
:quit